Introducing the New Way to Shop from Home/Iceland.iso/pc/noqtinternetaccess.dir/00047_Script_jump to frame

Text File | 2003-03-05 | 12KB | 319 lines

-- DESCRIPTION --

on getBehaviorDescription me
  return \
    "JUMP TO MOVIE BUTTON" & RETURN & RETURN & \
    "A click on the sprite makes the playback head jump to any other movie available to your system. " & \
    "An optional marker name can be used to jump to a precise point in the new movie. " & \
    "(Use the 'Jump to Marker Button' behavior to jump to a marker in the current movie)." & RETURN & RETURN & \
    "In order to make use of the Play and Return option, place a Play Done command in the destination movie." & RETURN & RETURN & \
    "This behavior is designed for use with the 'Jump Back Button'. " & \
    "You can set it to record the movie name and the frame number of the current marker so that the 'Jump Back Button' can subsequently return. " & \
    "NOTE: This feature relies on a global variable: gNavigationButtonList." & RETURN & RETURN & \
    "PERMITTED MEMBER TYPES" & RETURN & \
    "Graphic members" & RETURN & RETURN & \
    "PARAMETERS:" & RETURN & \
    "* Movie to jump to" & RETURN & RETURN & \
    "If the target movie is in the same folder as the current movie then you need only enter the name of the movie. " & \
    "If the movie is in a different folder, then enter the full or relative path name to the target movie." & RETURN & RETURN & \
    "* Marker to jump to in the new movie (optional)" & RETURN & \
    "* 'Go to' or 'Play and return'?" & RETURN & \
    "* Remember current marker for Back button?" & RETURN & RETURN & \
    "Select 'Remember current marker for Back button' to ensure that the behavior 'remembers' which markers have already been visited." & RETURN & RETURN & \
    "Use the associated 'Jump Back Button' behavior on a separate sprite to return to visited movies in reverse order." & RETURN & RETURN & \
    "ASSOCIATED BEHAVIORS:" & RETURN & \
    "+ Jump to Marker Button" & RETURN & \
    "+ Jump Back Button" & RETURN & \
    "+ Jump Forward Button" & RETURN & \
    "+ Push Button (to alter rollover / mouseDown states)"
end getBehaviorDescription


on getBehaviorTooltip me
  return \
    "Use with graphic members." & RETURN & RETURN & \
    "Jumps to a specified movie on mouseUp." & RETURN & RETURN & \
    "Use this behavior with the 'Jump Back Button' to allow the user to return to visited movies."
end getBehaviorTooltip




-- NOTES FOR DEVELOPERS --

-- The main handler is Jump, which is triggered by mouseUp.  The Initialize
-- handler prepares for the case where you have chosen a marker name for the
-- distant movie, and this marker does not in fact exist.  It also checks if
-- the global gNavigationButtonList has a valid structure (if necessary), or
-- warns you if you did not select a movie when you first attached the
-- behavior.

-- USE OF 'BACK/FORWARD BUTTON' BEHAVIORS
-- Information about what markers have already been visited is stored in a
-- global variable: gNavigationButtonList.  As a global, this variable is
-- available to all navigation behaviors, on any sprite in any movie.
--
-- gNavigationButtonList has the following structure:
--   [#stack [...], #index: [...], #forward: [...]]
-- Each of the subLists has the structure:
--   [[#frame: <integer>, #movie: <movieName>], [...]]
--
-- #index is not currently exploited.  It provides a list of all markers
-- visited, in the order of their first visit.  It could be used to create
-- a pop-up menu, or to check if a player had visited a particular scene.
--
-- Information concerning the most recently visited marker is stored in the
-- last item of the #stack list.  This item is copied to a local variable,
-- then removed from the #stack.  Information concerning the current marker
-- is appended to the #forward list, so that users can subsequently retrace
-- their steps.

-- TROUBLE-SHOOTING
-- Symptom: When you use the button, a dialog opens asking
--          "Where is <movieName>"
-- The behavior stores the target movie in the form of a relative path name.
-- If you move either the current movie or the target movie, or if you rename
-- the target movie, the behavior will subsequently contain invalid path data.
-- Re-open the Behavior Parameters dialog, relocate your target movie and
-- click OK.



-- HISTORY --

-- 10 September 1998: written for the D7 Behaviors Palette by James Newton
-- 22 October 1998:   "play"/"go to" added, choice of movie now made via fileIO
--                    #graphic used instead of #member in getPDL
-- 3 November 1998:   all member-swapping removed (use Push Button behavior)
--                    descriptions reworked
--  5 January   2000: updated to D8 <km>


-- PROPERTIES --

-- error checking:
property getPDLError
property myBehaviorName
-- author-defined parameters:
property myDistantMovie
property myDistantMarker
property myJumpMode
property myReturn


-- EVENT HANDLERS --

on beginSprite me
  Initialize me
end beginSprite


on mouseUp me
  Jump me
end prepareFrame



-- CUSTOM HANDLERS --

on Initialize me -- SENT BY beginSprite

  -- Can't test markers until in distant movie, so remember behavior name
  myBehaviorName = string (me)
  delete word 1 of myBehaviorName
  delete the last word of myBehaviorName
  delete the last word of myBehaviorName

  -- Global variable
  if myReturn then
    global gNavigationButtonList -- Only declared if it is to be used

    if voidP (gNavigationButtonList) then
      -- Initialize gNavigationButtonList
      gNavigationButtonList = [#stack: [], #forward: [], #index: []]
    else -- Is it the right global?
      if gNavigationButtonList.ilk <> #propList then
        errorAlert (me, #invalidGlobal, gNavigationButtonList)
      else if not gNavigationButtonList.findPos(#stack) then
        errorAlert (me, #invalidGlobal, gNavigationButtonList)
      else if not gNavigationButtonList.findPos(#index) then
        errorAlert (me, #invalidGlobal, gNavigationButtonList)
      else if not gNavigationButtonList.findPos(#forward) then
        errorAlert (me, #invalidGlobal, gNavigationButtonList)
      end if
    end if
  end if
  -- End of error checking

  case myDistantMarker of
    EMPTY, " ": myDistantMarker = 0
    otherwise
      -- Must be in myDistantMovie to know if myDistantMarker is a valid name
  end case
end Initialize


on Jump me -- Sent by mouseUp

  currentMarker = [#frame: marker (0), #movie: the movieName]

  if myReturn then
    -- Remember where to come back to
    global gNavigationButtonList -- Only declared if it is to be used

    -- Add to #stack
    gNavigationButtonList.stack.append(currentMarker)
    -- Check if currentMarker is already in #index
    if not gNavigationButtonList.index.getPos(currentMarker) then
      gNavigationButtonList.index.append(currentMarker)
    end if
    -- Empty #forward list
    gNavigationButtonList.forward = []
  end if

  -- Jump to chosen frame
  if myJumpMode = "Go to" then
    go marker (myDistantMarker) of movie myDistantMovie
  else
    play marker (myDistantMarker) of movie myDistantMovie
  end if
  -- Retrospective error check
  if the movieName = myDistantMovie then
    if the frameLabel <> myDistantMarker then
      ErrorAlert (me, #invalidMarker, currentMarker)
    end if
  end if
  -- End of retrospective error check
end Jump


on substituteStrings(me, parentString, childStringList) --------------
  -- Sent by errorAlert
  --
  -- * Modifies parentString so that the strings which appear as
  --   properties in childStringList are replaced by the values
  --   associated with those properties.
  --
  -- <childStringList> has the format ["^1": "replacement string"]
  --------------------------------------------------------------------

  i = childStringList.count()
  repeat while i
    tempString = ""
    dummyString  = childStringList.getPropAt(i)
    replacement  = childStringList[i]
    lengthAdjust = dummyString.char.count - 1
    repeat while TRUE
      position = offset(dummyString, parentString)
      if not position then
        parentString = tempString&parentString
        exit repeat
      else
        if position <> 1 then
          tempString = tempString&parentString.char[1..position - 1]
        end if
        tempString = tempString&replacement
        delete parentString.char[1..position + lengthAdjust]
      end if
    end repeat
    i = i - 1
  end repeat

  return parentString
end substituteStrings



-- ERROR CHECKING __

on errorAlert me, theError, data
  -- sent by getPropertyDescriptionList, Initialize
  -- Determine the behavior's name
  behaviorName = string (me)
  delete word 1 of behaviorName
  delete the last word of behaviorName
  delete the last word of behaviorName
  -- Convert #data to useful value
  case data.ilk of
    #void: data = "<void>"
    #symbol: data = "#"&data
  end case

  case theError of

    #getPDL_Invalid:
      tError1 = "BEHAVIOR ERROR: Frame ^0, Sprite ^1"
      tError1 = substituteStrings(me, tError1, ["^0":the frame, "^1": the currentSpriteNum])
      tError2 = "Parameters for behavior ^0 have not been correctly set. " & \
    "Select a valid movie name in the Behavior Parameters dialog."
      tError2 =  substituteStrings(me, tError2, ["^0":myBehaviorName])
      tError3 = "Current movie = ^0"
      tError3 = substituteStrings(me, tError3, ["^0":data])
      alert(tError1 & RETURN & RETURN & tError2 & RETURN & RETURN & tError3)
      halt

    #invalidGlobal:
      tError1 = "BEHAVIOR ERROR: Frame ^0, Sprite ^1"
      tError1 = substituteStrings(me, tError1, ["^0":the frame, "^1": the currentSpriteNum])
      tError2 = "Behavior ^0 requires a global gNavigationButtonList with the following" & RETURN & \
    " structure:"
      tError2 =  substituteStrings(me, tError2, ["^0":myBehaviorName])
      tError3 = "[#stack [...], #index: [...], #forward: [...]]"
      tError4 = "Current value = ^0"
      tError4 = substituteStrings(me, tError4, ["^0":data])
      alert(tError1 & RETURN & RETURN & tError2 & RETURN & RETURN & tError3 & RETURN & RETURN & tError4)
      abort

    #invalidMarker:
      if the runMode = "Author" then
        put RETURN & the labelList
        tError1 = "BEHAVIOR ERROR: ^0, Sprite ^1"
        tError1 = substituteStrings(me, tError1, ["^0":data, "^1": the currentSpriteNum])
        tError2 = "Behavior ^0"
        tError2 =  substituteStrings(me, tError2, ["^0":myBehaviorName])
        tError3 = "There is no marker ^0 in movie ^1. " & \
    "Enter a valid marker (see Message Window) in the Behavior Parameters dialog."
        tError3 =  substituteStrings(me, tError3, ["^0":QUOTE & myDistantMarker & QUOTE, "^1":myDistantMovie])
        alert(tError1 & RETURN & RETURN & tError2 & RETURN & RETURN & tError3)
      end if
  end case
end errorAlert


-- AUTHOR-DEFINED PARAMETERS --


on isOKToAttach (me, aSpriteType, aSpriteNum)
  return aSpriteType = #graphic
end on


on getPropertyDescriptionList me

  if not the currentSpriteNum then exit

  return \
[ \
 #myDistantMarker: \
 [ \
  #comment: "Marker in the other movie (optional)", \
  #format:  #string, \
  #default: " " \
  ], \
 #myJumpMode: \
 [ \
  #comment: "Jump Mode", \
  #format:  #string, \
  #range:  ["Go to", \
            "Play and Return"], \
  #default: "Go to" \
 ], \
 #myReturn: \
 [ \
  #comment: "Remember current marker for Back button?", \
  #format:  #boolean, \
  #default:  TRUE \
 ] \
]
end getPropertyDescriptionList